您的位置: 首页 > 技术文档 > 多媒体制作 > AS3自写类整理笔记:ByteLoader类
AS3自写类整理笔记:ClassLoader类 回到列表 FLASH小游戏开发 第四节
 AS3自写类整理笔记:ByteLoader类

作者:iamsun1550 时间: 2008-06-03 文档类型:原创 来自:蓝色理想

该类的主要功能是把swf,jpg,png,gif等文件以字节的形式加载进来
以便于使用Loader.loadBytes方法,重复加载使用素材
如果图片格式为jpg,并且是渐进式格式jpeg,那么该类还可以帮助你边加载边显示

index.base.net.byteLoader类讲解:
基本功能按字节加载图片,swf等

构造函数
public function ByteLoader(url:String = "")
如果传入了参数url,则立即执行加载!

load 加载方法
public function load(_url:String):void
开始加载,_url是加载的地址

updata 更新数据方法
public function updata():void
更新缓冲区的可读字节

close 关闭方法
public function close():void
类使用完毕,清除所有无用的数据,也可以用来强行关闭数据流,停止下载

data 属性
public var data:ByteArray
返回加载的字节

url 属性
public var url:String
返回加载的url

isLoad 属性(只读)
public function get isLoad():Boolean
返回是否有数据在加载

ProgressEvent.PROGRESS 事件
加载的过程中调度,并附带加载情况

Event.COMPLETE 事件
加载完毕调度

例子:

import index.base.net.ByteLoader;

var bl:ByteLoader = new ByteLoader;
bl.load("http://www.xiaos8.com/uploads/pro/50preso3a2.swf");
bl.addEventListener(Event.COMPLETE,completeFun);
bl.addEventListener(ProgressEvent.PROGRESS,progressFun);

function completeFun(e:Event):void{
  var loader:Loader = new Loader;
  loader.loadBytes(bl.data);
  addChild(loader);
  bl.removeEventListener(Event.COMPLETE,completeFun);
  bl.removeEventListener(ProgressEvent.PROGRESS,progressFun);
  bl.close();
  bl = null;
}

function progressFun(e:ProgressEvent):void{
  trace(e.bytesLoaded);
  //如果是渐进式格式的jpeg图片,那么在发布这个事件的时候读取字节,用Loader.loadBytes加载,就可以形成边加载边显示
}

源代码

package index.base.net{
 
  import flash.events.EventDispatcher;
  import flash.events.ProgressEvent;
  import flash.events.Event;
  import flash.utils.ByteArray;
  import flash.net.URLStream;
  import flash.net.URLRequest;
 
  public class ByteLoader extends EventDispatcher{
   
    public var url:String;
    public var data:ByteArray;
    private var stream:URLStream;
   
    public function ByteLoader(url:String = ""){
      if(url != ""){
        load(url);
      }
    }
   
    //加载
    public function load(_url:String):void{
      url = _url;
      data = new ByteArray;
      stream = new URLStream;
      stream.load(new URLRequest(url));
      stream.addEventListener(Event.COMPLETE,completeFun);
      stream.addEventListener(ProgressEvent.PROGRESS,progressFun);
    }
   
    //加载中
    private function progressFun(e:ProgressEvent):void{
      if(stream.bytesAvailable == 0) return;
      updata();
      dispatchEvent(e);
    }
   
    //加载完成
    private function completeFun(e:Event):void{
      stream.removeEventListener(Event.COMPLETE,completeFun);
      stream.removeEventListener(ProgressEvent.PROGRESS,progressFun);
      updata();
      if(isLoad) stream.close();
      dispatchEvent(e);
    }
   
    //更新数据
    public function updata():void{
      if(isLoad) stream.readBytes(data,data.length);
    }
   
    //清除数据
    public function close():void{
      if(isLoad) stream.close();
      stream = null;
      data = null;
    }
   
    //获取是否有数据在加载
    public function get isLoad():Boolean{
      if(stream == null) return false;
      return stream.connected;
    }
  }
}

经典论坛交流
http://bbs.blueidea.com/thread-2842832-1-1.html

本文链接:http://www.blueidea.com/tech/multimedia/2008/5841.asp 

出处:蓝色理想
责任编辑:bluehearts

◎进入论坛RIA设计与应用版块参加讨论

相关文章 更多相关链接
AS3自写类整理笔记:ClassLoader类
AS3自写类整理笔记:Dot类
AS3自写类整理笔记:类的分包处理
Making Things Move 第一章
通用滑动门类
作者文章
AS3自写类整理笔记:ClassLoader类
AS3自写类整理笔记:Dot类
AS3自写类整理笔记:类的分包处理
热门搜索:CSS Fireworks 设计比赛 网页制作 web标准 用户体验 UE photoshop Dreamweaver Studio8 Flash 手绘 CG
站点最新 站点最新列表
周大福“敬•自然”设计大赛开启
国际体验设计大会7月将在京举行
中国国防科技信息中心标志征集
云计算如何让安全问题可控
云计算是多数企业唯一拥抱互联网的机会
阿里行云
云手机年终巨献,送礼标配299起
阿里巴巴CTO王坚的"云和互联网观"
1499元买真八核 云OS双蛋大促
首届COCO桌面手机主题设计大赛
栏目最新 栏目最新列表
浅谈JavaScript编程语言的编码规范
如何在illustrator中绘制台历
Ps简单绘制一个可爱的铅笔图标
数据同步算法研究
用ps作简单的作品展示页面
CSS定位机制之一:普通流
25个最佳最闪亮的Eclipse开发项目
Illustrator中制作针线缝制文字效果
Photoshop制作印刷凹凸字体
VS2010中创建自定义SQL Rule
分享按钮

蓝色理想版权申明:除部分特别声明不要转载,或者授权我站独家播发的文章外,大家可以自由转载我站点的原创文章,但原作者和来自我站的链接必须保留(非我站原创的,按照原来自一节,自行链接)。文章版权归我站和作者共有。

转载要求:转载之图片、文件,链接请不要盗链到本站,且不准打上各自站点的水印,亦不能抹去我站点水印。

特别注意:本站所提供的摄影照片,插画,设计作品,如需使用,请与原作者联系,版权归原作者所有,文章若有侵犯作者版权,请与我们联系,我们将立即删除修改。

您的评论
用户名:  口令:
说明:输入正确的用户名和密码才能参与评论。如果您不是本站会员,你可以注册 为本站会员。
注意:文章中的链接、内容等需要修改的错误,请用报告错误,以利文档及时修改。
不评分 1 2 3 4 5
注意:请不要在评论中含与内容无关的广告链接,违者封ID
请您注意:
·不良评论请用报告管理员,以利管理员及时删除。
·尊重网上道德,遵守中华人民共和国的各项有关法律法规
·承担一切因您的行为而直接或间接导致的民事或刑事法律责任
·本站评论管理人员有权保留或删除其管辖评论中的任意内容
·您在本站发表的作品,本站有权在网站内转载或引用
·参与本评论即表明您已经阅读并接受上述条款
推荐文档 | 打印文档 | 评论文档 | 报告错误  
专业书推荐 更多内容
网站可用性测试及优化指南
《写给大家看的色彩书1》
《跟我去香港》
众妙之门—网站UI 设计之道
《Flex 4.0 RIA开发宝典》
《赢在设计》
犀利开发—jQuery内核详解与实践
作品集 更多内容

杂⑦杂⑧ Gold NORMANA V2